Deliverect
Aperçu
Ce document explique comment configurer les améliorations de l'intégration Deliverect introduites dans la version 5.17.
Prérequis
- Les caisses doivent utiliser POS 5.17 ou une version ultérieure
- Chrome est installé sur les caisses
Intégration du paiement de la disposition
Paiement le jour même du kilométrage des livreurs et des pourboires par carte de crédit. PAR détermine le mode de paiement de chaque livreur (carte de paie, paie ou espèces) et gère les connexions aux fournisseurs de paiement. PAR se charge de cumuler les montants, d'appeler appelle un service et d'afficher le résultat.
Comment ça marche
-
Le livreur s'enregistre sur le terminal Deliverect.
- Un nouveau service (l'accumulateur de kilométrage étendu) le kilométrage et l'identifiant de l'employé.
- L'enregistrement indique aussi que l'employé est admissible à un paiement pour cette date comptable.
-
Le service convertit les mètres en milles, applique le taux de l'emplacement et cumule le kilométrage par employé, par emplacement et par date comptable.
-
Lorsque le livreur se déconnecte, le service totalise tous les pourboires par carte de crédit, avant et après ajustement, à partir de l'état des commandes de la caisse. Cela comprend toutes les commandes dont l'employé était responsable pendant ce quart, et pas seulement les livraisons. Les pourboires en espèces ne sont jamais inclus.
-
Le service appelle l'API de paie une fois par quart
POST /payroll/webhook/pizza/paycardavec le kilométrage, les pourboires, l'identifiant de paie, l'identifiant de l'emplacement et la date comptable. -
PAR renvoie le montant total et la disposition. Tout total supérieur à 1 000 $ est renvoyé en espèces. Si l'intégration de la carte de paie échoue, PAR POS renvoie Espèces, et s'il est inaccessible après plusieurs tentatives, le paiement bascule vers la paie.
-
Un gérant appuie sur un bouton de la caisse, ce qui ouvre un rapport dans le navigateur indiquant le montant et la disposition pour tous les livreurs déconnectés.
- Si la disposition est Espèces, le gérant peut, s'il le souhaite, enregistrer un retrait de petite caisse pour réconcilier le tiroir-caisse.
Configuration requise
Google Chrome DOIT être installé sur les caisses pour que le rapport s'ouvre. Avant d'utiliser le script du rapport, effectuez aussi la configuration du Script d'installation de Google Chrome sous Scripts nécessaires pour Deliverect à la fin de ce document, même si Chrome est déjà installé. Cette entrée de script définit les fonctions ResolveChromePath et FindChromeExe requises par le script du rapport.
-
Identifiant de paie : L'appel à PAR nécessite l'identifiant de paie de l'employé, et non son identifiant d'employé.
- L'identifiant de paie se trouve dans le fichier
Staff.json(il faut télécharger les paramètres de PAR POS). - Une fois le fichier téléchargé, recherchez
PayrollId.- Vous pouvez appuyer sur Ctrl + F pour effectuer une recherche.
- Incluez les guillemets dans la recherche.
- L'identifiant de paie se trouve dans le fichier
-
Bouton de la caisse : Un bouton est configuré pour lancer le rapport dans le navigateur. Il utilise un comportement VBScript
ExecuteScript, basé sur le script de lancement Deliverect existant, et doit être protégé par une permission réservée aux gérants et aux niveaux supérieurs.
Ajoutez le script aux Fonctions de script :
- Connectez-vous à l'Éditeur de paramètres
- Cliquez sur Fonctions de script
- Cliquez sur Ajouter une nouvelle fonction de script
- Dans le champ Nom, saisissez
RetrieveDriverCompensationReport - Dans la zone de texte, saisissez le script répertorié dans la section Scripts nécessaires pour Deliverect de ce document, intitulé 'RetrieveDriverCompensationReport.vbs'. Enregistrez aussi les fonctions auxiliaires
ResolveChromePathetFindChromeExeprésentées dans la section Script d'installation de Google Chrome. Ces deux fonctions sont requises même si Google Chrome est déjà installé. - Cliquez sur OK
- Cliquez sur Enregistrer et Publier
Ajoutez le bouton de script à la Mise en page :
-
Connectez-vous à l'Éditeur de paramètres
-
Cliquez sur Mise en page
-
Sélectionnez le panneau souhaité
-
Cliquez sur le bouton Ajouter un nouveau contrôle
-
Cliquez sur le menu déroulant à côté de Comportement
-
Sélectionnez Exécuter le script
-
Cliquez sur le bouton Configurer
-
Ajoutez ce qui suit :
RetrieveDriverCompensationReport Functions2.GetBusinessDate(), Functions2.GetLocationId(), Functions2.GetFrontendServiceSecurityToken()
-
Apportez les modifications souhaitées à la position et à l'apparence du bouton
-
Réglez la Permission à une permission accordée uniquement aux gérants et aux niveaux supérieurs
-
Cliquez sur Enregistrer et Publier
-
Jetons d'ajustement des pourboires : le client doit déployer des jetons de paiement pour l'ajustement des pourboires sans carte présente.
-
Petite caisse (facultatif) : Créez-en une par livreur, ou utilisez le champ de description pour consigner le nom du livreur.
- Connectez-vous à l'Éditeur de paramètres
- Cliquez sur Comptes de petite caisse
- Cliquez sur Ajouter un nouveau compte de petite caisse
- Saisissez le nom souhaité dans le champ Nom
- Le Type de compte doit être réglé à Retrait d'espèces
- Cochez la case à gauche de Description obligatoire pour exiger une description lorsque le retrait d'espèces est effectué à la caisse.
- Cliques sur Enregister et Publier
Flux de travail
-
Le livreur se déconnecte de la caisse comme d'habitude. Rien de nouveau ne lui est affiché, et la caisse n'est pas verrouillée pendant que PAR traite le paiement.
-
Un gérant (ou un niveau supérieur) appuie sur le nouveau bouton de la caisse. Il est protégé par une permission parce qu'il affiche les renseignements de paie de tous les employés.
-
Le bouton ouvre un rapport en lecture seule dans le navigateur (Chrome) qui répertorie tous les livreurs déconnectés pour la date comptable. Il indique, pour chaque livreur, son nom ou son identifiant, le montant du kilométrage, le montant des pourboires, le total et la disposition (carte de paie, paie ou espèces).
-
Si un livreur ne figure pas encore dans la liste, ou si les données semblent incomplètes, l'horodatage de dernière mise à jour indique si le traitement est encore en attente. Fermez le rapport et rouvrez-le peu après.
-
Payez le livreur selon la disposition.
- Carte de paie ou paie: il n'y a rien d'autre à faire à la caisse.
- Espèces: payez le livreur à même le tiroir-caisse. Il est recommandé (mais non obligatoire) d'enregistrer un retrait de petite caisse afin que le tiroir balance. Le bordereau s'imprime pour la signature du livreur. Le retrait d'espèces est associé au tiroir-caisse et n'apparaîtra pas sur la fermeture de caisse du livreur. Pour l'attribuer, utilisez une petite caisse par livreur ou inscrivez le nom du livreur dans le champ de description.
-
Fermez le rapport à l'aide de son contrôle de sortie, afin que les fenêtres Chrome ne s'accumulent pas.
(BNZ-1849, PDOC-4433)
Attribution du taux de rémunération des livreurs
Utilisée lorsque des clients rémunèrent leurs livreurs à un taux inférieur pendant qu'ils sont sur la route. Le POS ne peut pas changer de poste en cours de quart; le temps sur la route est donc rémunéré au taux du poste avec lequel le livreur s'est connecté. Cette fonctionnalité transmet les minutes sur la route à PAR POS afin qu'il puisse appliquer le bon taux.
Comment ça marche
-
Le client envoie les événements de départ et de retour du livreur à nouveau service. Le nouveau service les transmet à une file d'attente, au moyen du transport convenu.
-
Les événements sont regroupés par
tripId, ce qui donne un segment par trajet.- Par exemple, des trajets de 30 et de 20 minutes deviennent deux segments, parce que le service a besoin des durées pour calculer les heures supplémentaires.
-
Chaque segment est affecté au quart dont les heures de début et de fin l'encadrent.
-
PAR POS extrait les données une seule fois après la fin de journée, un appel par emplacement et par date comptable.
-
La réponse est organisée par
shiftId, avecoverrideJobIdindiqué une fois par employé et les segments répertoriés sous chaque quart.- Les minutes de remplacement sont un sous-ensemble des minutes du quart.
-
PAR POS recherche le taux à partir du
overridejobIdet gère les heures supplémentaires.
Configuration requise
-
Poste Livreur sur la route :
- Exigence relative à la configuration des employés : Il doit être attribué à chaque employé, y compris les gérants et les chefs d'équipe qui effectuent des livraisons. Sans lui, aucun remplacement n'est produit et toutes leurs minutes sont rémunérées au taux du poste avec lequel ils se sont connectés.
- Nom du poste : le nom du poste doit contenir On Road (sur la route), le client doit le conserver uniforme d'un emplacement à l'autre.
- Connectez-vous au Portail d'administration
- Cliquez sur Personnel
- Cliquez sur Emplois
- Cliquez sur Ajouter un nouvel emploi
- Dans le champ Nom, saisissez On Road
- Dans la section Livraison, cochez la case à côté de Livreur
- Configurez le reste de la page comme vous le souhaitez
- Cliquez sur Enregistrer
-
Ajouter le poste On Road à tous les employés livreurs
- Cliquez sur Personnel
- Cliquez sur Employés
- Cliquez sur l'employé souhaité
- Cliquez sur Ajouter un emploi
- Cliquez sur la liste déroulante sous le champ Emploi
- Sélectionnez le poste On Road créé ci-dessus
- Sélectionnez le Niveau de sécurité souhaité
- Saisissez le Taux de rémunération souhaité
- Cliquez sur Enregistrer
- Répétez les étapes 2 à 9 pour tous les employés livreurs qui utiliseront cette fonctionnalité
-
PAR met la file d'attente en place et fournit un accès en écriture entre comptes.
-
PAR POS enregistre le type d'événement de départ, ajoute un champ
tripIdet ajoute un nouveau service.
Flux de travail
- Les livreurs se connectent une seule fois sous un seul poste, et le temps sur la route provient des événements de départ et de retour.
(BNZ-1896, PDOC-4433)
Scripts nécessaires pour Deliverect
RetrieveDriverCompensationReport.vbs
- Script qui ouvrira le rapport de rémunération des livreurs :
Sub RetrieveDriverCompensationReport(businessDate, locationId, token)
Dim objFSO, objHTTP, shell, stream
Dim tempRoot, reportDir, reportPath, fileUrl, chromeExePath, targetUrl
Const BASE_URL = "https://prod.api.partech.io/pj/mileage/v1/CompensationReport"
targetUrl = BASE_URL & "?businessDate=" & businessDate & "&locationId=" & locationId
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set shell = CreateObject("WScript.Shell")
' One fixed file in %TEMP%\CompReports, overwritten every run.
' Falls back to %TEMP% if the subfolder can't be made.
tempRoot = objFSO.GetSpecialFolder(2).Path
reportDir = objFSO.BuildPath(tempRoot, "CompReports")
If Not objFSO.FolderExists(reportDir) Then
On Error Resume Next
objFSO.CreateFolder reportDir
On Error GoTo 0
If Not objFSO.FolderExists(reportDir) Then reportDir = tempRoot
End If
reportPath = objFSO.BuildPath(reportDir, "compreport.html")
Set objHTTP = CreateObject("MSXML2.ServerXMLHTTP.6.0")
On Error Resume Next
Err.Clear
objHTTP.Open "GET", targetUrl, False
objHTTP.SetRequestHeader "Authorization", "Bearer " & token
objHTTP.Send
If Err.Number <> 0 Then
Functions2.ShowMessage "Échec de la requête HTTP : " & Err.Description
On Error GoTo 0
Exit Sub
End If
On Error GoTo 0
If LenB(objHTTP.responseBody) = 0 Then
Functions2.ShowMessage "Le service a retourné HTTP " & objHTTP.Status & " " & objHTTP.StatusText
Exit Sub
End If
On Error Resume Next
Err.Clear
Set stream = CreateObject("ADODB.Stream")
stream.Type = 1 ' adTypeBinary
stream.Open
stream.Write objHTTP.responseBody
stream.SaveToFile reportPath, 2 ' adSaveCreateOverWrite
stream.Close
If Err.Number <> 0 Then
Functions2.ShowMessage "Impossible d'écrire le fichier du rapport : " & Err.Description
On Error GoTo 0
Exit Sub
End If
On Error GoTo 0
chromeExePath = ResolveChromePath(objFSO)
If chromeExePath = "" Then
Functions2.ShowMessage "Erreur : Google Chrome est introuvable ou n'a pas pu être installé."
Exit Sub
End If
fileUrl = "file:///" & Replace(reportPath, "\", "/")
shell.Run """" & chromeExePath & """ --app=""" & fileUrl & _
""" --start-maximized --no-default-browser-check", 1, False
End Sub
Script d'installation de Google Chrome :
- Connectez-vous à l'Éditeur de paramètres
- Cliquez sur Fonctions de script
- Cliquez sur Ajouter une nouvelle fonction de script
- Dans le champ Nom, saisissez
InstallGoogleChrome - Dans la zone de texte, saisissez ce qui suit :
Function ResolveChromePath(objFSO)
Dim waitUntil
ResolveChromePath = FindChromeExe(objFSO)
If ResolveChromePath <> "" Then Exit Function
InstallGoogleChrome
waitUntil = DateAdd("s", 10, Now())
Do Until Now() > waitUntil
Loop
ResolveChromePath = FindChromeExe(objFSO)
End Function
Function FindChromeExe(objFSO)
Dim paths, i
paths = Array( _
"C:\Program Files (x86)\Google\Chrome\Application\chrome.exe", _
"C:\Program Files\Google\Chrome\Application\chrome.exe")
FindChromeExe = ""
For i = 0 To UBound(paths)
If objFSO.FileExists(paths(i)) Then
FindChromeExe = paths(i)
Exit Function
End If
Next
End Function
